Home page  Up a level  Display Fields command source  Display Fields control language source  Display Fields display file source  Display Fields help PanelGroup source  Display Fields RPG Source  Display Fields printer file source  Display Fields CL Subprogram 1  Display Fields CL subprogram 2  Display Fields Logicals  Display Fields create command source

Display Fields printer file source

      *********************************************************************
      ***        NAME: DSPFLDPR                           TYPE: PRTF    ***
      *** DESCRIPTION: Display the fields, and the attributes of the    ***
      *** fields in a file; also, mark the key fields in the list with  ***
      *** their order number.  The program will also show a window      ***
      *** listing just the key fields in order, another window that     ***
      *** shows the select/omit field values, and a window showing the  ***
      *** data base relations.                                          ***
      ***                                                               ***
      *** Copyright 1995 by John H. Daily III                           ***
      *********************************************************************

      *********************************************************************
      *** Primary headings - prints on all pages.                       ***
      *********************************************************************
     A          R MAINHEADER
     A                                      SKIPB(001)
     A                                     4
     A                                      'DspFld'
     A                                    33
     A                                      'File Field Description Listing'
     A                                    87
     A                                      'Page:'
     A                                    +1
     A                                      PAGNBR
     A                                      EDTCDE(Z)
     A                                    89
     A                                      DATE
     A                                      EDTCDE(Y)
     A                                      SPACEB(001)
     A                                    10
     A                                      'Name of File:'
     A                                      SPACEB(002)
     A            R@FILE        10A  O    +1
     A                                    42
     A                                      'Source:'
     A            R@SRCFILE     10A  O    +1
     A                                    +5
     A                                      'Create:'
     A            R@CRTDATE      8S 0O    +1
     A                                      EDTCDE(Y)
     A            R@CRTTIME      6S 0O    +1
     A                                      EDTWRD('  :  :  ')
     A                                    15
     A                                      'Library:'
     A                                      SPACEB(001)
     A            R@LIB         10A  O    +1
     A                                    +7
     A                                      'Library:'
     A            R@SRCLIB      10A  O    +1
     A                                    +5
     A                                      'Change:'
     A            R@CHGDATE      8S 0O    +1
     A                                      EDTCDE(Y)
     A            R@CHGTIME      6S 0O    +1
     A                                      EDTWRD('  :  :  ')
     A                                    10
     A                                      'Type of file:'
     A                                      SPACEB(001)
     A            R@TYPE        10A  O    24
     A                                    +8
     A                                      'Member:'
     A            R@SRCMBR      10A  O    +1
     A                                    +7
     A                                      'Save:'
     A            R@SAVEDATE     8S 0O    +1
     A                                      EDTCDE(Y)
     A            R@SAVETIME     6S 0O    +1
     A                                      EDTWRD('  :  :  ')
      *********************************************************************
      *** Sub headings - only prints on first page.                     ***
      *********************************************************************
     A          R SUBHEADER1
     A                                      SPACEA(001)
     A                                      SPACEB(001)
     A                                     4
     A                                      'Record format name:'
     A            R@FORMAT      10A  O    24
     A                                   +31
     A                                      'Source:'
     A            R@SRCDATE      8S 0O    +1
     A                                      EDTCDE(Y)
     A            R@SRCTIME      6S 0O    +1
     A                                      EDTWRD('  :  :  ')
     A                                     6
     A                                      'Number of fields:'
     A                                      SPACEB(001)
     A            R@NBRFIELD     7   O    24
     A                                   +33
     A                                      'Org Src:'
     A            R@ORGSRCDT     8S 0O    +1
     A                                      EDTCDE(Y)
     A            R@ORGSRCTM     6S 0O    +1
     A                                      EDTWRD('  :  :  ')
     A                                     9
     A                                      'Record Length:'
     A                                      SPACEB(001)
     A            R@RECLEN       7A  O    24
     A                                   +36
     A                                      'Size:'
     A            R@SIZE        20A  O    +1
     A                                     5
     A                                      'Number of Records:'
     A                                      SPACEB(001)
     A            R@RECCOUNT    20A  O    +1
     A                                     6
     A                                      'File Description:'
     A                                      SPACEB(001)
     A            R@TEXT        50   O    +1
     A                                    27
     A                                      'Start'
     A                                      SPACEB(003)
     A                                    34
     A                                      'Field'
     A                                    41
     A                                      'Dec'
     A                                    41
     A                                      'Pos'
     A                                      UNDERLINE
     A                                      SPACEB(001)
     A                                     4
     A                                      'Field Name'
     A                                      UNDERLINE
     A                                    +2
     A                                      'Data Type'
     A                                      UNDERLINE
     A                                    26
     A                                      '  Pos '
     A                                      UNDERLINE
     A                                    34
     A                                      'Length'
     A                                      UNDERLINE
     A                                    45
     A                                      'Field Description                 -
     A                                                      '
     A                                      UNDERLINE
      *********************************************************************
      *** Field listing.                                                ***
      *********************************************************************
     A          R FIELDETAIL
     A                                      SPACEA(001)
     A            R1FIELD   R        O     4
     A                                      REFFLD(QWHDRFFD/WHFLDE FLDLST)
     A            R1TYPE         9A  O    +2
     A            R1START   R        O    +1
     A                                      REFFLD(QWHDRFFD/WHIBO FLDLST)
     A                                      EDTCDE(2)
     A            R1LENGTH  R        O    +2
     A                                      REFFLD(QWHDRFFD/WHFLDB FLDLST)
     A                                      EDTCDE(2)
     A            R1DECIMAL      2A  O    +1
     A            R1TEXT    R        O    +2
     A                                      REFFLD(QWHDRFFD/WHFTXT FLDLST)
      *********************************************************************
      *** Key field listing.                                            ***
      *********************************************************************
     A          R KEYSHEADER
     A                                      SPACEA(001)
     A                                     1
     A                                      '-----------------------------------
     A                                      ------------------------------------
     A                                      -------------------------'
     A                                    33
     A                                      'Key Fields'
     A                                      SPACEB(001)
     A                                      HIGHLIGHT
     A                                      UNDERLINE
     A                                     1
     A                                      'Seq'
     A                                      SPACEB(001)
     A                                      HIGHLIGHT
     A                                      UNDERLINE
     A                                     6
     A                                      'Field     '
     A                                      HIGHLIGHT
     A                                      UNDERLINE
     A                                    +2
     A                                      'A/D'
     A                                      HIGHLIGHT
     A                                      UNDERLINE
     A                                    +2
     A                                      'Description                       -
     A                                                      '
     A                                      HIGHLIGHT
     A                                      UNDERLINE
     A          R KEYSDETAIL
     A                                      SPACEA(001)
     A            R3SEQUENCE     2S 0O     1
     A                                      EDTCDE(Z)
     A            R3KEYFIELD    10A  O     6
     A            R3DIRECT       1A  O    19
     A            R3DESCRIPT    50A  O    +3
      *********************************************************************
      *** Select/Omit field listing.                                    ***
      *********************************************************************
     A          R SELHEAD
     A                                      SPACEA(001)
     A                                     1
     A                                      '-----------------------------------
     A                                      ------------------------------------
     A                                      -------------------------'
     A                                    16
     A                                      'Select/Omit fields'
     A                                      SPACEB(001)
     A                                      HIGHLIGHT
     A                                      UNDERLINE
     A                                     1
     A                                      'S/O'
     A                                      SPACEB(001)
     A                                      HIGHLIGHT
     A                                      UNDERLINE
     A                                     6
     A                                      'Field     '
     A                                      HIGHLIGHT
     A                                      UNDERLINE
     A                                    +2
     A                                      'Comp'
     A                                      HIGHLIGHT
     A                                      UNDERLINE
     A                                    +2
     A                                      'Value                        '
     A                                      HIGHLIGHT
     A                                      UNDERLINE
     A          R SELDETAIL
     A                                      SPACEA(001)
     A            R4SELOMIT      1A  O     2
     A            R4SELFIELD    10A  O     6
     A            R4COMPARE      2A  O    19
     A            R4VALUE       30A  O    +3
     A          R NOSELFLDS
     A                                      SPACEA(001)
     A                                      SPACEB(001)
     A                                     9
     A                                      'This file has no Select/omit field-
     A                                      s'
      *********************************************************************
      *** Database relations listing.                                   ***
      *********************************************************************
     A          R DBRHEADER
     A                                      SPACEA(001)
     A                                     1
     A                                      '-----------------------------------
     A                                      ------------------------------------
     A                                      -------------------------'
     A                                    29
     A                                      'Data Base Relations'
     A                                      HIGHLIGHT
     A                                      UNDERLINE
     A                                      SPACEB(001)
     A                                     1
     A                                      'File      '
     A                                      SPACEB(002)
     A                                      HIGHLIGHT
     A                                      UNDERLINE
     A                                    +2
     A                                      'Library   '
     A                                      HIGHLIGHT
     A                                      UNDERLINE
     A                                    +2
     A                                      'Text/Key Fields                   -
     A                                                      '
     A                                      HIGHLIGHT
     A                                      UNDERLINE
     A          R DBRDETAIL
     A                                      SPACEA(001)
     A            R5FILE        10A  O     1
     A            R5LIB         10A  O    +2
     A            R5TEXT        50A  O    +2
     A          R NOKEYFLDS
     A                                      SPACEA(001)
     A                                      SPACEB(001)
     A                                     9
     A                                      'Key Fields:'
     A                                    +2
     A                                      'This file has no key fields'
     A*%%***********************************************************************
     A*%%SS
     A*%%CL 001
     A*%%CP+999CRTPRTF
     A*%%CP+    OPTION(*NOSRC *NOLIST)
     A*%%CP+    CPI(12)
     A*%%CP+    PAGRTT(0)
     A*%%CP+    REPLACE(*NO)
     A*%%CP+    FILE(JHDUTIL/DSPFLDPR)
     A*%%CP+    DEVTYPE(*SCS)
     A*%%CP     PAGESIZE(*N       096      *N     )
     A*%%***********************************************************************