Home page  Up a level  You are here  CL Menu Program Source  PopMnu Data Area Layout  PopMnu Data Area Edit Program  PopMnu Screen Shots

PopMnu Display File Source

 This is the display file for the CL Menu program.  It is used by both the menu program and the data area edit program. 

      *********************************************************************
      ***        NAME: POPMNUDF                                         ***
      *** DESCRIPTION: Display for menu program POPMNU.  Allows up to   ***
      *** 80 options on each of up to 10 menus.  Allows you to define   ***
      *** up to 16 group jobs that are accessible from any of the menus ***
      ***                                                               ***
      *** Copyright 1990 by John H. Daily III                           ***
      *********************************************************************
      *** SCRN01 - main menu display                                    ***
      *** SCRN02 - show non-visible options                             ***
      *** SCRN03 - get menu option number to change                     ***
      *** SCRN04 - menu option change window                            ***
      *** SCRN05 - password change window                               ***
      *** SCRN06 - function key password change window                  ***
      *** SCRN07 - window for showing menu option                       ***
      *** SCRN08 - window for showing underlying menu command           ***
      *** SCRN09 - group job setup/change window                        ***
      *** SCRN10 - function key definition window                       ***
      *** SCRN11 - maintain POPMNU data area                            ***
      *** SCRN12 - function key option change window                    ***
      *** SCRN13 - unused screen for ASSUME keyword                     ***
      *** SCRN14 - display hex color values                             ***
      *** SCRN15 - defined group jobs                                   ***
      *** SCRN16 - select menu to show                                  ***
      *********************************************************************
     A                                      DSPSIZ(24 80 *DS3)
     A                                      CHGINPDFT
     A                                      PRINT
     A                                      HELP(98)
      *********************************************************************
      *** Main menu display                                             ***
      *********************************************************************
     A          R SCRN01
     A                                      TEXT('Main Menu Display')
     A                                      CA01(98)
     A                                      CA02(02)
     A                                      CA03(03)
     A                                      CF04(04)
     A                                      CA05(05)
     A                                      CA06(06)
     A                                      CA07(07)
     A                                      CA08(08)
     A                                      CA09(09)
     A                                      CF10(10)
     A                                      CA11(11)
     A                                      CA12(12)
     A                                      CA13(13)
     A                                      CA14(14)
     A                                      CA15(15)
     A                                      CA16(16)
     A                                      CA17(17)
     A                                      CA18(18)
     A                                      CA19(19)
     A                                      CA20(20)
     A                                      CA21(21)
     A                                      CA22(22)
     A                                      CA23(23)
     A                                      CA24(24)
     A                                      ROLLUP(25)
     A                                      ROLLDOWN(26)
     A                                      KEEP
     A                                      RTNCSRLOC(*MOUSE &S1RTNROW &S1RTNCO-
     A                                      L)
     A                                      OVERLAY
     A                                      MOUBTN(*ULP CA24)
     A            S1RTNROW       3S 0H
     A            S1RTNCOL       3S 0H
     A            S1DATE        10A  O  1  2DSPATR(RI)
     A                                      COLOR(BLU)
     A            S1HEADING     58A  O  1 13DSPATR(RI)
     A                                      COLOR(TRQ)
     A            S1TIME         8A  O  1 72DSPATR(RI)
     A                                      COLOR(BLU)
     A            S1BLANK       79A  O  2  1
     A            FLD001      1600A  O  3  1
     A            FLD101        79A  O 23  2
     A            FLD094        20A  O 24  2COLOR(RED)
     A                                      DSPATR(RI)
     A            SINP           2A  B 24 23CHECK(ER)
     A                                      COLOR(PNK)
     A                                      DSPATR(UL)
     A                                 24 28'Cur Lib:'
     A                                      COLOR(RED)
     A                                      DSPATR(RI)
     A            S1CURLIB      10A  O 24 37DSPATR(RI)
     A  97                                  DSPATR(BL)
     A N97                                  COLOR(RED)
     A  97                                  COLOR(BLU)
     A            S1GROUPS      32A  O 24 48
      *********************************************************************
      *** Show non-visible options and function keys.                   ***
      *********************************************************************
     A          R SCRN02
     A                                      TEXT('Options 81-99 and Function Ke-
     A                                      ys')
     A                                      WINDOW(4 28 16 24 *NOMSGLIN)
     A                                  1  6'Menu Options:'
     A                                      DSPATR(HI)
     A                                  2  1'90 - Select Menu'
     A                                  3  1'91 - Select Screen Color'
     A                                  4  1'92 - Edit Function Keys'
     A                                  5  1'93 - End all Group Jobs'
     A                                  6  1'94 - Edit Data Area'
     A                                  7  1'95 - Lock terminal'
     A                                  8  1'96 - Edit menu options'
     A                                  9  1'97 - New lock password'
     A                                 10  1'98 - Show Defined Groups'
     A                                 11  1'99 - Signoff'
     A                                 13  6'Function Keys:'
     A                                      DSPATR(HI)
     A                                 14  1'F21 - End program'
     A                                 15  1'F22 - Disconnect'
     A                                 16  1'F24 - Signoff'
      *********************************************************************
      *** Get menu option number to change from user                    ***
      *********************************************************************
     A          R SCRN03
     A                                      WINDOW(3 10 4 30 *NOMSGLIN)
     A                                      TEXT('Select an option to change')
     A                                      CA03(03)
     A                                      CF04(04)
     A                                      CA12(12)
     A                                      CLRL(*NO)
     A                                      OVERLAY
     A                                      WDWBORDER((*COLOR BLU))
     A                                      WDWTITLE((*TEXT 'Select an Option'))
     A                                  1  5'Group Job?'
     A N57                                  DSPATR(ND)
     A            S3GROUP        1A  B  1 16DSPATR(HI)
     A                                      DSPATR(UL)
     A N57                                  DSPATR(ND)
     A N57                                  DSPATR(PR)
     A                                      CHECK(ER)
     A                                  1 20'(Y/N/Blank)'
     A N57                                  DSPATR(ND)
     A N58                              2  1'Option number:'
     A  58                                  DSPATR(ND)
     A  58                              2  9'Group:'
     A N58                                  DSPATR(ND)
     A N58        S3NBR          3A  B  2 16DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER RZ)
     A  58                                  DSPATR(ND PR)
     A  59                                  DSPATR(PC)
     A  58        S3GRPOPT       1   B  2 16DSPATR(HI PC)
     A                                      DSPATR(UL)
     A                                      VALUES('A' 'B' 'C' 'D' 'E' 'F' 'G' -
     A                                      'H' 'I' 'J' 'K' 'L' 'M' 'N' 'O' 'P')
     A N58                                  DSPATR(ND)
     A N58                                  DSPATR(PR)
     A                                  4  1'F12=Cancel'
     A                                      COLOR(BLU)
      *********************************************************************
      *** Menu option change window                                     ***
      *********************************************************************
     A          R SCRN04
     A                                      WINDOW(3 10 18 58 *NOMSGLIN)
     A                                      TEXT('Change a menu option')
     A                                      CA03(03)
     A                                      CF04(04)
     A                                      CF10(10)
     A                                      CA12(12)
     A                                      CLRL(*NO)
     A                                      OVERLAY
     A                                      WDWBORDER((*COLOR TRQ))
     A                                      WDWTITLE((*TEXT 'Change a menu opti-
     A                                      on'))
     A                                  1  2'Number:'
     A            S4NBR          4A  O  1 11DSPATR(HI)
     A                                  2  4'Text:'
     A            S4TEXT        14A  B  2 11DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(LC)
     A                                  2 39'Color:'
     A            S4COLOR        2   B  2 46DSPATR(HI)
     A                                      DSPATR(UL)
     A                                  3  1'Command:'
     A            S4COMMAND    658A  B  3 11CNTFLD(047)
     A                                      DSPATR(HI)
     A                                      DSPATR(UL)
     A                                 18  1'F3=Exit'
     A                                      COLOR(BLU)
     A                                 18 13'F4=Prompt'
     A                                      COLOR(BLU)
     A                                 18 27'F10=No prompt'
     A                                      COLOR(BLU)
     A                                 18 45'F12=Cancel'
     A                                      COLOR(BLU)
      *********************************************************************
      *** Password change screen                                        ***
      *********************************************************************
     A          R SCRN05
     A                                      TEXT('Change the password')
     A                                      CA03(03)
     A                                      CF04(04)
     A                                      CA12(12)
     A                                      CLRL(*NO)
     A                                      OVERLAY
     A                                      WINDOW(3 10 5 30 *NOMSGLIN)
     A                                      WDWBORDER((*COLOR TRQ))
     A                                      WDWTITLE((*TEXT 'Change your Passwo-
     A                                      rd'))
     A                                  2  2'New Password:'
     A            @PWORD        14A  B  2 16DSPATR(HI)
     A                                      DSPATR(UL)
     A                                  4  2'F3=Exit'
     A                                  4 20'F12=Cancel'
      *********************************************************************
      *** Function key password change window                           ***
      *********************************************************************
     A          R SCRN06
     A                                      TEXT('Change the FKey password')
     A                                      CA12(12)
     A                                      CLRL(*NO)
     A                                      OVERLAY
     A                                      WINDOW(15 20 3 20 *NOMSGLIN)
     A                                      WDWBORDER((*COLOR TRQ))
     A            @ONE           2  0B  2  4DSPATR(HI UL)
     A                                      EDTWRD('  ')
     A            @TWO           2  0B  2  8DSPATR(HI UL)
     A                                      EDTWRD('  ')
     A            @THREE         2  0B  2 12DSPATR(HI UL)
     A                                      EDTWRD('  ')
     A            @FOUR          2  0B  2 16DSPATR(HI UL)
     A                                      EDTWRD('  ')
      *********************************************************************
      *** Window for showing menu option                                ***
      *********************************************************************
     A          R SCRN07
     A                                      TEXT('Display a menu option')
     A                                      CLRL(*NO)
     A                                      OVERLAY
     A                                      WINDOW(&@ROW &@COL 1 60 *NOMSGLIN)
     A                                      WDWBORDER((*COLOR BLU))
     A            @ROW           2  0P
     A            @COL           3  0P
     A            @CMD          60   O  1  1
      *********************************************************************
      *** Window for showing underlying menu option                     ***
      *********************************************************************
     A          R SCRN08
     A                                      TEXT('Display command for menu opt')
     A                                      OVERLAY
     A                                      KEEP
     A                                      WINDOW(&@ROW1 &@COL1 1 18 *NOMSGLIN)
     A                                      WDWBORDER((*COLOR BLU))
     A            @ROW1          2  0P
     A            @COL1          3  0P
     A            @MENU1        18      1  1
      *********************************************************************
      *** Group job setup/change window                                 ***
      *********************************************************************
     A          R SCRN09
     A                                      WINDOW(12 5 9 65 *NOMSGLIN)
     A                                      TEXT('Define a group job for menu')
     A                                      CA12(12)
     A                                      WDWBORDER((*COLOR BLU))
     A                                  1 24'Group Job Definition'
     A                                      DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      COLOR(RED)
     A                                  2  8'Option:'
     A            S9OPTION       1A  O  2 16
     A                                  3  3'Option Text:'
     A            S9TEXT        14A  B  3 16DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(LC)
     A                                  4  4'Group Name:'
     A            S9GRPNAME     10A  O  4 16DSPATR(HI)
     A                                  5  4'Group Text:'
     A            S9GRPTEXT     50A  B  5 16DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(LC)
     A                                  6  7'Program:'
     A            S9GRPPROG     10A  B  6 16DSPATR(HI)
     A                                      DSPATR(UL)
     A                                  7  1'Hilight Begin:'
     A            S9GRPHIBEG     4D  B  7 16DSPATR(HI)
     A                                      DSPATR(UL)
     A                                  8  3'Hilight End:'
     A            S9GRPHIEND     4D  B  8 16DSPATR(HI)
     A                                      DSPATR(UL)
     A                                  9  1'F12=Cancel'
     A                                      COLOR(BLU)
      *********************************************************************
      *** Function key definition window                                ***
      *********************************************************************
     A          R SCRN10
     A                                      TEXT('Define function keys')
     A                                      CA12(12)
     A                                      WINDOW(5 2 16 74 *NOMSGLIN)
     A                                      WDWBORDER((*COLOR PNK))
     A                                  1 26'Function Key Definitions'
     A                                      DSPATR(HI)
     A                                  3  1'F01'
     A            @OPT1          1A  B  3  5DSPATR(UL)
     A                                      DSPATR(HI)
     A            @FUNCT1       30A  O  3  7
     A                                  3 39'F13'
     A            @OPT13         1A  B  3 43DSPATR(HI)
     A                                      DSPATR(UL)
     A            @FUNCT13      30A  O  3 45
     A                                  4  1'F02'
     A            @OPT2          1A  B  4  5DSPATR(UL)
     A                                      DSPATR(HI)
     A            @FUNCT2       30A  O  4  7
     A                                  4 39'F14'
     A            @OPT14         1A  B  4 43DSPATR(HI)
     A                                      DSPATR(UL)
     A            @FUNCT14      30A  O  4 45
     A                                  5  1'F03'
     A            @OPT3          1A  B  5  5DSPATR(UL)
     A                                      DSPATR(HI)
     A            @FUNCT3       30A  O  5  7
     A                                  5 39'F15'
     A            @OPT15         1A  B  5 43DSPATR(HI)
     A                                      DSPATR(UL)
     A            @FUNCT15      30A  O  5 45
     A                                  6  1'F04'
     A            @OPT4          1A  B  6  5DSPATR(UL)
     A                                      DSPATR(HI)
     A            @FUNCT4       30A  O  6  7
     A                                  6 39'F16'
     A            @OPT16         1A  B  6 43DSPATR(HI)
     A                                      DSPATR(UL)
     A            @FUNCT16      30A  O  6 45
     A                                  7  1'F05'
     A            @OPT5          1A  B  7  5DSPATR(UL)
     A                                      DSPATR(HI)
     A            @FUNCT5       30A  O  7  7
     A                                  7 39'F17'
     A            @OPT17         1A  B  7 43DSPATR(HI)
     A                                      DSPATR(UL)
     A            @FUNCT17      30A  O  7 45
     A                                  8  1'F06'
     A            @OPT6          1A  B  8  5DSPATR(UL)
     A                                      DSPATR(HI)
     A            @FUNCT6       30A  O  8  7
     A                                  8 39'F18'
     A            @OPT18         1A  B  8 43DSPATR(HI)
     A                                      DSPATR(UL)
     A            @FUNCT18      30A  O  8 45
     A                                  9  1'F07'
     A            @OPT7          1A  B  9  5DSPATR(UL)
     A                                      DSPATR(HI)
     A            @FUNCT7       30A  O  9  7
     A                                  9 39'F19'
     A            @OPT19         1A  B  9 43DSPATR(HI)
     A                                      DSPATR(UL)
     A            @FUNCT19      30A  O  9 45
     A                                 10  1'F08'
     A            @OPT8          1A  B 10  5DSPATR(UL)
     A                                      DSPATR(HI)
     A            @FUNCT8       30A  O 10  7
     A                                 10 39'F20'
     A            @OPT20         1A  B 10 43DSPATR(HI)
     A                                      DSPATR(UL)
     A            @FUNCT20      30A  O 10 45
     A                                 11  1'F09'
     A            @OPT9          1A  B 11  5DSPATR(UL)
     A                                      DSPATR(HI)
     A            @FUNCT9       30A  O 11  7
     A                                 11 39'F21'
     A            @OPT21         1A  B 11 43DSPATR(HI)
     A                                      DSPATR(UL)
     A            @FUNCT21      30A  O 11 45
     A                                 12  1'F10'
     A            @OPT10         1A  B 12  5DSPATR(UL)
     A                                      DSPATR(HI)
     A            @FUNCT10      30A  O 12  7
     A                                 12 39'F22'
     A            @OPT22         1A  B 12 43DSPATR(HI)
     A                                      DSPATR(UL)
     A            @FUNCT22      30A  O 12 45
     A                                 13  1'F11'
     A            @OPT11         1A  B 13  5DSPATR(UL)
     A                                      DSPATR(HI)
     A            @FUNCT11      30A  O 13  7                                    
     A                                 13 39'F23'
     A            @OPT23         1A  B 13 43DSPATR(HI)
     A                                      DSPATR(UL)
     A            @FUNCT23      30A  O 13 45
     A                                 14  1'F12'
     A            @OPT12         1A  B 14  5DSPATR(UL)
     A                                      DSPATR(HI)
     A            @FUNCT12      30A  O 14  7
     A                                 14 39'F24'
     A            @OPT24         1A  B 14 43DSPATR(HI)
     A                                      DSPATR(UL)
     A            @FUNCT24      30A  O 14 45
     A                                 16  1'F3=Exit'
     A                                      COLOR(BLU)
     A                                 16 13'F5=Refresh'
     A                                      COLOR(BLU)
     A                                 16 28'F12=Cancel'
     A                                      COLOR(BLU)
      *********************************************************************
      *** Maintain POPMNU data area                                     ***
      *********************************************************************
     A          R SCRN11
     A                                      TEXT('Maintain POPMNU data area')
     A                                      CA03(03 'Exit')
     A                                      CF10(10 'Update')
     A                                      CA12(12 'Cancel')
     A                                  1  2'SCRN11'
     A                                  1 32'Pop-Up Menu System'
     A                                      DSPATR(HI)
     A                                  1 73DATE
     A                                      EDTCDE(Y)
     A                                  2  2USER
     A                                  2 23'Maintain Attention Program Data Ar-
     A                                      ea'
     A                                  2 73TIME
     A                                  4 45'Menu'
     A                                      DSPATR(HI)
     A                                      DSPATR(UL)
     A                                  4 50'Description                   '
     A                                      DSPATR(HI)
     A                                      DSPATR(UL)
     A                                  5 11'Group Job:'
     A                                      DSPATR(RI)
     A                                      COLOR(BLU)
     A                                  5 24'Display:  '
     A                                      DSPATR(RI)
     A                                      COLOR(BLU)
     A                                  5 46'0'
     A            S11MENU0      30   B  5 50DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(LC)
     A            S11GROUP1     10A  B  6 11DSPATR(UL)
     A                                      DSPATR(HI)
     A            S11DISP1      10A  B  6 24DSPATR(UL)
     A                                      DSPATR(HI)
     A                                  6 46'1'
     A            S11MENU1      30   B  6 50DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(LC)
     A            S11GROUP2     10A  B  7 11DSPATR(UL)
     A                                      DSPATR(HI)
     A            S11DISP2      10A  B  7 24DSPATR(UL)
     A                                      DSPATR(HI)
     A                                  7 46'2'
     A            S11MENU2      30   B  7 50DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(LC)
     A            S11GROUP3     10A  B  8 11DSPATR(UL)
     A                                      DSPATR(HI)
     A            S11DISP3      10A  B  8 24DSPATR(UL)
     A                                      DSPATR(HI)
     A                                  8 46'3'
     A            S11MENU3      30   B  8 50DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(LC)
     A            S11GROUP4     10A  B  9 11DSPATR(UL)
     A                                      DSPATR(HI)
     A            S11DISP4      10A  B  9 24DSPATR(UL)
     A                                      DSPATR(HI)
     A                                  9 46'4'
     A            S11MENU4      30   B  9 50DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(LC)
     A            S11GROUP5     10A  B 10 11DSPATR(UL)
     A                                      DSPATR(HI)
     A            S11DISP5      10A  B 10 24DSPATR(UL)
     A                                      DSPATR(HI)
     A                                 10 46'5'
     A            S11MENU5      30   B 10 50DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(LC)
     A                                 11 46'6'
     A            S11MENU6      30   B 11 50DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(LC)
     A                                 12 46'7'
     A            S11MENU7      30   B 12 50DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(LC)
     A                                 13 12'Used Date:'
     A            S11DATE        8Y 0B 13 23EDTWRD('  /  /    ')
     A                                      EDTMSK('  &  &    ')
     A                                      DSPATR(UL)
     A                                      DSPATR(HI)
     A                                 13 46'8'
     A            S11MENU8      30   B 13 50DSPATR(HI)
     A                                      DSPATR(UL)
     A                                 14  5'Atn Program Name:'
     A            S11ATNPGM     10A  B 14 23DSPATR(UL)
     A                                      DSPATR(HI)
     A                                 14 46'9'
     A            S11MENU9      30   B 14 50DSPATR(HI)
     A                                      DSPATR(UL)
     A                                 15  7'Last Time Used:'
     A            S11LASTTIM     6Y 0B 15 23EDTWRD('  :  :  ')
     A                                      EDTMSK('  &  &  ')
     A                                      DSPATR(HI)
     A                                      DSPATR(UL)
     A                                 16  4'Refresh Wait Time:'
     A            S11REFWAIT     3A  B 16 23DSPATR(UL)
     A                                      DSPATR(HI)
     A                                 16 30'(Seconds)'
     A                                 17  7'Lock Wait Time:'
     A            S11LCKWAIT     4Y 0B 17 23EDTWRD('  :  ')
     A                                      EDTMSK('  &  ')
     A                                      DSPATR(HI)
     A                                      DSPATR(UL)
     A                                 17 30'(Min:Sec)'
     A                                 18  6'Utility Library:'
     A            S11UTILLIB    10A  B 18 23DSPATR(HI)
     A                                      DSPATR(UL)
     A                                 19  6'Remove Commands:'
     A            S11REMOVE      1A  B 19 23DSPATR(HI)
     A                                      DSPATR(UL)
     A                                 20  7'Show Group Job:'
     A            S11SHOWGRP     1A  B 20 23DSPATR(HI)
     A                                      DSPATR(UL)
     A                                 23  2'F10=Update'
     A                                      COLOR(BLU)
     A                                 23 17'F12=Cancel'
     A                                      COLOR(BLU)
      *********************************************************************
      *** Function key option change window                             ***
      *********************************************************************
     A          R SCRN12
     A                                      TEXT('Change a function key command-
     A                                      ')
     A                                      CA03(03)
     A                                      CF04(04)
     A                                      CA12(12)
     A                                      CLRL(*NO)
     A                                      OVERLAY
     A                                      WINDOW(7 10 9 60 *NOMSGLIN)
     A                                      WDWBORDER((*COLOR RED))
     A                                      WDWTITLE((*TEXT 'Change a function -
     A                                      key') *CENTER)
     A                                  1 11'Function Key:'
     A            S12FKEY        3A  O  1 25DSPATR(HI)
     A                                  2  3'Function Key Command:'
     A            S12CMD1       35A  B  2 25DSPATR(HI)
     A                                      DSPATR(UL)
     A            S12CMD2       58A  B  3  2DSPATR(HI)
     A                                      DSPATR(UL)
     A            S12CMD3       58A  B  4  2DSPATR(HI)
     A                                      DSPATR(UL)
     A            S12CMD4       58A  B  5  2DSPATR(HI)
     A                                      DSPATR(UL)
     A            S12CMD5       58A  B  6  2DSPATR(HI)
     A                                      DSPATR(UL)
     A            S12CMD6       58A  B  7  2DSPATR(HI)
     A                                      DSPATR(UL)
     A                                  9  2'F3=Exit'
     A                                      COLOR(BLU)
     A                                  9 14'F4=Prompt'
     A                                      COLOR(BLU)
     A                                  9 28'F12=Cancel'
     A                                      COLOR(BLU)
      *********************************************************************
      *** Unused screen for ASSUME keyword                              ***
      *********************************************************************
     A          R SCRN13
     A                                      TEXT('Dummy screen for ASSUME')
     A                                      ASSUME
     A                                  1  6'  '
      *********************************************************************
      *** Hex color values.                                             ***
      *********************************************************************
     A          R SCRN14
     A                                      TEXT('Show colors')
     A                                      WINDOW(5 25 14 29 *NOMSGLIN)
     A            FLD0001        5A  O  3  4
     A            FLD0002        5A  O  4  4
     A            FLD0003        5A  O  5  4
     A            FLD0004        5A  O  6  4
     A            FLD0005        5A  O  7  4
     A            FLD0006        5A  O  8  4
     A            FLD0007        5A  O  9  4
     A            FLD0008        5A  O 10  4
     A            FLD0009        5A  O 11  4
     A            FLD0010        5A  O 12  4
     A            FLD0011        5A  O  3 14
     A            FLD0012        5A  O  4 14
     A            FLD0013        5A  O  5 14
     A            FLD0014        5A  O  6 14
     A            FLD0015        5A  O  7 14
     A            FLD0016        5A  O  8 14
     A            FLD0017        5A  O  9 14
     A            FLD0018        5A  O 10 14
     A            FLD0019        5A  O 11 14
     A            FLD0020        5A  O 12 14
     A            FLD0021        5A  O  3 24
     A            FLD0022        5A  O  4 24
     A            FLD0023        5A  O  5 24
     A            FLD0024        5A  O  6 24
     A            FLD0025        5A  O  7 24
     A            FLD0026        5A  O  8 24
     A            FLD0027        5A  O  9 24
     A            FLD0028        5A  O 10 24
     A            FLD0029        5A  O 11 24
     A            FLD0030        5A  O 12 24
     A                                  1  8'Hex Color Values'
     A                                      DSPATR(HI)
     A                                 14 19'F12=Cancel'
     A                                      COLOR(BLU)
     A            S14SEL01       1A  I  3  2DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S14SEL02       1A  I  4  2DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S14SEL03       1A  I  5  2DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S14SEL04       1A  I  6  2DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S14SEL05       1A  I  7  2DSPATR(HI)
     A                                      DSPATR(UL)                          
     A                                      CHECK(ER)
     A            S14SEL06       1A  I  8  2DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S14SEL07       1A  I  9  2DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S14SEL08       1A  I 10  2DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S14SEL09       1A  I 11  2DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S14SEL10       1A  I 12  2DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S14SEL11       1A  I  3 12DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S14SEL12       1A  I  4 12DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S14SEL13       1A  I  5 12DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S14SEL14       1A  I  6 12DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S14SEL15       1A  I  7 12DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S14SEL16       1A  I  8 12DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S14SEL17       1A  I  9 12DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S14SEL18       1A  I 10 12DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S14SEL19       1A  I 11 12DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S14SEL20       1A  I 12 12DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S14SEL21       1A  I  3 22DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S14SEL22       1A  I  4 22DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S14SEL23       1A  I  5 22DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S14SEL24       1A  I  6 22DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S14SEL25       1A  I  7 22DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S14SEL26       1A  I  8 22DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S14SEL27       1A  I  9 22DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S14SEL28       1A  I 10 22DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S14SEL29       1A  I 11 22DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S14SEL30       1A  I 12 22DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
      *********************************************************************
      *** Defined group jobs.                                           ***
      *********************************************************************
     A          R SCRN15
     A                                      TEXT('Show defined/undefined groups-
     A                                      ')
     A                                      WINDOW(3 25 17 32 *NOMSGLIN)
     A                                  1  1'Def'
     A                                      DSPATR(HI)
     A                                      DSPATR(UL)
     A                                  1  5'Group  '
     A                                      DSPATR(HI)
     A                                      DSPATR(UL)
     A                                  1 13'Description:        '
     A                                      DSPATR(HI)
     A                                      DSPATR(UL)
     A            S15GRP1        1A  O  2  2
     A  41                                  COLOR(BLU)
     A                                  2  5'Group1 '
     A  41                                  COLOR(BLU)
     A            S15GRPD1      20   O  2 13
     A            S15GRP2        1A  O  3  2
     A  42                                  COLOR(BLU)
     A                                  3  5'Group2 '
     A  42                                  COLOR(BLU)
     A            S15GRPD2      20   O  3 13
     A            S15GRP3        1A  O  4  2
     A  43                                  COLOR(BLU)
     A                                  4  5'Group3 '
     A  43                                  COLOR(BLU)
     A            S15GRPD3      20   O  4 13
     A            S15GRP4        1A  O  5  2
     A  44                                  COLOR(BLU)
     A                                  5  5'Group4 '
     A  44                                  COLOR(BLU)
     A            S15GRPD4      20   O  5 13
     A            S15GRP5        1A  O  6  2
     A  45                                  COLOR(BLU)
     A                                  6  5'Group5 '
     A  45                                  COLOR(BLU)
     A            S15GRPD5      20   O  6 13
     A            S15GRP6        1A  O  7  2
     A  46                                  COLOR(BLU)
     A                                  7  5'Group6 '
     A  46                                  COLOR(BLU)
     A            S15GRPD6      20   O  7 13
     A            S15GRP7        1A  O  8  2
     A  47                                  COLOR(BLU)
     A                                  8  5'Group7 '
     A  47                                  COLOR(BLU)
     A            S15GRPD7      20   O  8 13
     A            S15GRP8        1A  O  9  2
     A  48                                  COLOR(BLU)
     A                                  9  5'Group8 '
     A  48                                  COLOR(BLU)
     A            S15GRPD8      20   O  9 13
     A            S15GRP9        1A  O 10  2
     A  49                                  COLOR(BLU)
     A                                 10  5'Group9 '
     A  49                                  COLOR(BLU)
     A            S15GRPD9      20   O 10 13
     A            S15GRP10       1A  O 11  2
     A  50                                  COLOR(BLU)
     A                                 11  5'Group10'
     A  50                                  COLOR(BLU)
     A            S15GRPD10     20   O 11 13
     A            S15GRP11       1A  O 12  2
     A  51                                  COLOR(BLU)
     A                                 12  5'Group11'
     A  51                                  COLOR(BLU)
     A            S15GRPD11     20   O 12 13
     A            S15GRP12       1A  O 13  2
     A  52                                  COLOR(BLU)
     A                                 13  5'Group12'
     A  52                                  COLOR(BLU)
     A            S15GRPD12     20   O 13 13
     A            S15GRP13       1A  O 14  2
     A  53                                  COLOR(BLU)
     A                                 14  5'Group13'
     A  53                                  COLOR(BLU)
     A            S15GRPD13     20   O 14 13
     A            S15GRP14       1A  O 15  2
     A  54                                  COLOR(BLU)
     A                                 15  5'Group14'
     A  54                                  COLOR(BLU)
     A            S15GRPD14     20   O 15 13
     A            S15GRP15       1A  O 16  2
     A  55                                  COLOR(BLU)
     A                                 16  5'Group15'
     A  55                                  COLOR(BLU)
     A            S15GRPD15     20   O 16 13
     A            S15GRP16       1A  O 17  2
     A  56                                  COLOR(BLU)
     A                                 17  5'Group16'
     A  56                                  COLOR(BLU)
     A            S15GRPD16     20   O 17 13
      *********************************************************************
      *** Select menu to show.                                          ***
      *********************************************************************
     A          R SCRN16
     A                                      CA12(12)
     A                                      TEXT('Select menu to show')
     A                                      OVERLAY
     A                                      WINDOW(10 43 12 32 *NOMSGLIN)
     A                                  1 12'Select Menu'
     A                                      COLOR(PNK)
     A            S16OPT0        1   I  2  1DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S16MENU0      30   O  2  3
     A            S16OPT1        1   I  3  1DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S16MENU1      30   O  3  3
     A            S16OPT2        1   I  4  1DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S16MENU2      30   O  4  3
     A            S16OPT3        1   I  5  1DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S16MENU3      30   O  5  3
     A            S16OPT4        1   I  6  1DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S16MENU4      30   O  6  3
     A            S16OPT5        1   I  7  1DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S16MENU5      30   O  7  3
     A            S16OPT6        1   I  8  1DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S16MENU6      30   O  8  3
     A            S16OPT7        1   I  9  1DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S16MENU7      30   O  9  3
     A            S16OPT8        1   I 10  1DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S16MENU8      30   O 10  3
     A            S16OPT9        1   I 11  1DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S16MENU9      30   O 11  3
     A                                 12 12'F12=Cancel'
     A                                      COLOR(BLU)
      *********************************************************************
      *** Allowable menu hex color values.                              ***
      *********************************************************************
     A          R SCRN17
     A                                      TEXT('Show allowable menu colors')
     A                                      WINDOW(5 25 12 29 *NOMSGLIN)
     A            S17COLOR01     5A  O  3  4
     A            S17COLOR02     5A  O  4  4
     A            S17COLOR03     5A  O  5  4
     A            S17COLOR04     5A  O  6  4
     A            S17COLOR05     5A  O  7  4
     A            S17COLOR06     5A  O  8  4
     A            S17COLOR07     5A  O  9  4
     A            S17COLOR08     5A  O 10  4
     A            S17COLOR09     5A  O  3 14
     A            S17COLOR10     5A  O  4 14
     A            S17COLOR11     5A  O  5 14
     A            S17COLOR12     5A  O  6 14
     A            S17COLOR13     5A  O  7 14
     A            S17COLOR14     5A  O  8 14
     A            S17COLOR15     5A  O  9 14
     A            S17COLOR16     5A  O 10 14
     A            S17COLOR17     5A  O  3 24
     A            S17COLOR18     5A  O  4 24
     A            S17COLOR19     5A  O  5 24
     A            S17COLOR20     5A  O  6 24
     A            S17COLOR21     5A  O  7 24
     A            S17COLOR22     5A  O  8 24
     A            S17COLOR23     5A  O  9 24
     A            S17COLOR24     5A  O 10 24
     A                                 12 19'F12=Cancel'
     A                                      COLOR(BLU)
     A            S17SEL01       1A  I  3  2DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S17SEL02       1A  I  4  2DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S17SEL03       1A  I  5  2DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S17SEL04       1A  I  6  2DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S17SEL05       1A  I  7  2DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S17SEL06       1A  I  8  2DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S17SEL07       1A  I  9  2DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S17SEL08       1A  I 10  2DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S17SEL09       1A  I  3 12DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S17SEL10       1A  I  4 12DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S17SEL11       1A  I  5 12DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S17SEL12       1A  I  6 12DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S17SEL13       1A  I  7 12DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S17SEL14       1A  I  8 12DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S17SEL15       1A  I  9 12DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S17SEL16       1A  I 10 12DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S17SEL17       1A  I  3 22DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S17SEL18       1A  I  4 22DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S17SEL19       1A  I  5 22DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S17SEL20       1A  I  6 22DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S17SEL21       1A  I  7 22DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S17SEL22       1A  I  8 22DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S17SEL23       1A  I  9 22DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A            S17SEL24       1A  I 10 22DSPATR(HI)
     A                                      DSPATR(UL)
     A                                      CHECK(ER)
     A                                  1  1'Color Values for Menu Options'